Loading...
 

Arduino Ethernet Shield 2: Chat server

Chat server

This example shows you how to realize a simple chat server to send messagges to all connected clients.
To use the chat you need a telnet terminal.

Hardware

  • Arduino board
  • Arduino Ethernet Shield 2

Software

  • A software that implement a telnet communication, for example "PuTTY".

Circuit

Image
Mount your Ethenet shield 2 on an Arduino board and connect it to the network using the Ethernet cable.

Code

The first operation of this sketch is to include the "SPI.h" and "Ethernet2.h" libraries, after you must indicate the Shield MAC address and your IP adddress.
Also it is defined the port 23 for the telnet communication.
In the setup function is initialized the Serial communication and the Ethernet device.
Finally in the loop block starts the chat and all communication are shown on Serial monitor.
If you want add a new client in chat, you must open a telnet terminal to IP address shown on Serial monitor.
Now you can send messages at all clients.

The complete code and its detailed description are shown down.

Note:
You need the "SPI.h", "Ethernet2.h" libraries to use this sketch and you need to change the network settings in the sketch to correspond to your network.

/*
 Advanced Chat Server

 A more advanced server that distributes any incoming messages 
 to all connected clients but the client the message comes from.
 To use telnet to  your device's IP address and type.
 You can see the client's input in the serial monitor as well.
 Using an Arduino Wiznet Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 redesigned to make use of operator== 25 Nov 2013
 by Norbert Truchsess

 */
#include <SPI.h>
#include <Ethernet2.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network.
// gateway and subnet are optional:
byte mac[] = { 
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192,168,1, 177);
IPAddress gateway(192,168,1, 1);
IPAddress subnet(255, 255, 0, 0);


// telnet defaults to port 23
EthernetServer server(23);

EthernetClient clients[4];

void setup() {
  // initialize the ethernet device
  Ethernet.begin(mac, ip, gateway, subnet);
  // start listening for clients
  server.begin();
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  Serial.print("Chat server address:");
  Serial.println(Ethernet.localIP());
}

void loop() {
  // wait for a new client:
  EthernetClient client = server.available();

  // when the client sends the first byte, say hello:
  if (client) {

    boolean newClient = true;
    for (byte i=0;i<4;i++) {
      //check whether this client refers to the same socket as one of the existing instances:
      if (clients[i]==client) {
        newClient = false;
        break;
      }
    }

    if (newClient) {
      //check which of the existing clients can be overridden:
      for (byte i=0;i<4;i++) {
        if (!clients[i] && clients[i]!=client) {
          clients[i] = client;
          // clead out the input buffer:
          client.flush();
          Serial.println("We have a new client");
          client.print("Hello, client number: ");
          client.print(i);
          client.println();
          break;
        }
      }
    }

    if (client.available() > 0) {
      // read the bytes incoming from the client:
      char thisChar = client.read();
      // echo the bytes back to all other connected clients:
      for (byte i=0;i<4;i++) {
        if (clients[i] && (clients[i]!=client)) {
          clients[i].write(thisChar);
        }
      }
      // echo the bytes to the server as well:
      Serial.write(thisChar);
    }
  }
  for (byte i=0;i<4;i++) {
    if (!(clients[i].connected())) {
      // client.stop() invalidates the internal socket-descriptor, so next use of == will allways return false;
      clients[i].stop();
    }
  }
}